/**
* Copyright (c) 2007 Gerald Yeo  <gerald.yeo[@]gmail.com>
* All rights reserved.
* 
* Permission is hereby granted, free of charge, to any person obtaining a copy 
* of this software and associated documentation files (the "Software"), to deal 
* in the Software without restriction, including without limitation the rights 
* to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
* copies of the Software, and to permit persons to whom the Software is furnished 
* to do so, subject to the following conditions:
* 
* The above copyright notice and this permission notice shall be included in all 
* copies or substantial portions of the Software.
* 
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, 
* INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A 
* PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
* HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION 
* OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE 
* SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
* 
* SimpleButton class.
* 
* @author	Gerald Yeo
* @version	0.1
* 
* @usage	
* 			var btn = new SimpleButton();
* 			btn.release = function(targ){
* 				// code
* 			}
*/

package com.flashobscura.ui {
	import flash.display.DisplayObjectContainer;
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
	
	public class SimpleButton extends MovieClip {
		public var rollOver:Function;
		public var rollOut:Function;
		public var press:Function;
		public var release:Function;
		public var releaseOutside:Function;
		
		public function SimpleButton(handCursor:Boolean = false){
			showHandCursor(handCursor);
			addEventListener(MouseEvent.MOUSE_OVER, mouseOver, 	false, 0, true);
			addEventListener(MouseEvent.MOUSE_OUT, 	mouseOut, 	false, 0, true);
			addEventListener(MouseEvent.MOUSE_DOWN, mouseDown, 	false, 0, true);
		}
		
		//-- API
		
		/**
		* Set whether to show hand cursor.
		* 
		* @param	bool (Boolean)
		*/
		public function showHandCursor(bool:Boolean):void {
			buttonMode = bool;
		}
		
		//-- private
		
		private function mouseOver(evt:MouseEvent):void {
			if (rollOver != null && enabled) 
				rollOver(this);
		}
		
		private function mouseOut(evt:MouseEvent):void {
			if (rollOut != null && enabled) 
				rollOut(this);
		}
		
		private function mouseDown(evt:MouseEvent):void {
			if (enabled) {
				if (press != null) 
					press(this);
				
				stage.addEventListener(MouseEvent.MOUSE_UP, mouseUp, false, 0, true);
			}
		}
		
		private function mouseUp(evt:MouseEvent):void {
			if (enabled) {
				if (evt.target == this || contains(evt.target as DisplayObjectContainer)) {
					if (release != null ) 
						release(this);
				}
				else {
					if (releaseOutside != null) 
						releaseOutside(this, evt.currentTarget);
				}
				
				stage.removeEventListener(MouseEvent.MOUSE_UP, mouseUp, false);
			}
		}
	}
}